计算机等级考试二级VB常用算法(6)：排序

1、算法说明
1)        选择法排序  
(1)     从n个数中选出最小数的下标，出了循环，将最小数与第一个数交换位置；
(2)     除第一个数外，在剩下的n-1个数中再按方法（1）选出次小的数，与第二个数交换位置；
(3)     以此类推，最后构成递增序列。
譬如：
                                            8       6       9       3       2       7
第一轮交换后             2       6       9       3       8       7
第二轮交换后             2       3       9       6       8       7
第三轮交换后             2       3       6       9       8       7
第四轮交换后             2       3       6       7       8       9
第五轮无交换             2       3       6       7       8       9 
 
程序代码如下：
Private Sub xzPaiXu(a() As Double, sheng As Boolean)
    'a为需要排序的数组，sheng为True则为升序排列，为False，则为降序排列。
    Dim i As Integer, j As Integer
    Dim temp As Double
    Dim m As Integer
    For i = LBound(a) To UBound(a) - 1     '进行数组大小-1轮比较
        m = i                              '在第i轮比较时，假定第
                                           'i个元素为最值元素
        For j = i + 1 To UBound(a)         '在剩下的元素中找出最
                                           '值元素的下标并记录在m中
            If sheng Then                  '若为升序，则m记录最小元素
                                           '下标,否则记录最大元素下标
                If a(j) < a(m) Then m = j
            Else
                If a(j) > a(m) Then m = j
            End If
        Next j                             '将最值元素与第i个元素交换
        temp = a(i)
        a(i) = a(m)
        a(m) = temp
    Next i
End Sub 
 
调用该过程示例：
Option Base 1
Private Sub Command1_Click()
    Dim b(6) As Double
    b(1) = 8
    b(2) = 6
    b(3) = 9
    b(4) = 3
    b(5) = 2
    b(6) = 7
    Call xzPaiXu(b, True)
    For i% = 1 To 6
        Print b(i)
    Next
End Sub